100 '  VF.BAS     Dan Maguire  AC6LA
110 '
120 '  Calculate any one value from velocity factor equation
130 '  given the other three values.
140 '
150 COLOR 7,1
160 CLS
170 PRINT "--- VF ---";
180   PRINT "   Velocity factor equation in any form"
190 PRINT
200 PRINT "Enter values for any 3 of the 4 terms."
210 PRINT "Enter null for the unknown."
220 PRINT
230 '
240 INPUT "Number of wavelengths, N (or append 'd' for degrees)"; N$
250 IF N$ = "" THEN GOTO 280
260   IF RIGHT$(N$,1) <> "d" THEN N = VAL(N$): GOTO 280
270     N = VAL(LEFT$(N$,LEN(N$)-1)) / 360
280 PRINT
290 INPUT "Length of line in feet, L"; L
300 PRINT
310 INPUT "Frequency in MHz, F"; F
320 PRINT
330 IF N <> 0 AND L <> 0 AND F <> 0 THEN GOTO 410
340 INPUT "Velocity factor, VF"; VF
350 PRINT
360 '
370 IF N = 0 THEN GOTO 450
380 IF L = 0 THEN GOTO 490
390 IF F = 0 THEN GOTO 530
400 '
410 VF = (L * F) / (983.5712 * N)
420 PRINT "Velocity factor, VF ="; VF
430 GOTO 560
440 '
450 N = (L * F) / (983.5712 * VF)
460 PRINT "Number of wavelengths, N ="; N; "   (="; N*360; "degrees)"
470 GOTO 560
480 '
490 L = (N * 983.5712 * VF) / F
500 PRINT "Length of line in feet, L ="; L
510 GOTO 560
520 '
530 F = (N * 983.5712 * VF) / L
540 PRINT "Frequency in MHz, F ="; F
550 '
560 PRINT: PRINT: PRINT
570 PRINT "Press any key to exit ..."
580 DUM$ = INKEY$: IF DUM$ = "" THEN GOTO 580
590 COLOR 7,0: CLS: SYSTEM